通过模板生成静态页面示例
<!--模块文件(template.htm)-->
<html>
<head>
<title>%TITLE%</title>
</head>
<body>
%CONTENT%
</body>
</html>�
<!--TestTemplate.asp-->
<%
Dim fso,f
Dim strTitle,strContent,strOut
'创建文件系统对象
Set fso=Server.CreateObject("Scripting.FileSystemObject")
'打开网页模板文件，读取模板内容
Set f=fso.OpenTextFile(Server.MapPath("Template.htm"))
strOut=f.ReadAll
f.close
strTitle="这是生成的网页标题"
strContent="这是生成的网页内容"
'用真实内容替换模板中的标记
strOut=Replace(strOut,"%TITLE%",strTitle)
strOut=Replace(strOut,"%CONTENT%",strContent)
'创建要生成的静态页
Set f=fso.CreateTextFile(Server.MapPath("New.htm"),true)
'写入网页内容
f.WriteLine strOut
f.close
Response.Write "生成静态页成功！"
'释放文件系统对象
set f=Nothing
set fso=Nothing
%>
在静态页面中显示文章被阅读的次数
生成静态页面时会产生一个文章的id存到数据库中，那么我们在制作文章的模板的时候就可以在这个文章的id上做文章，文章模板包含以下语句：
<SCRIPT src="counter.asp?articleId=<%=#articleId#%>"></SCRIPT >
<b>说明：</b>
在利用模板生成文章时，把"#articleId#"进行模式匹配，替换为新添加的文章的id号。
counter.asp 文件为实现记数的asp文件
<%
'###################
'######开始#########
'BY 王向超
'###################
dim articleId,sqlStr,hits
articleId=int(trim(request.querystring("articleId")))
sqlStr="update articles set hits=hits+1 where articleId=" & articleId
'给文章点击数加1
conn.execute(sqlStr)
'读出文章点击数
hits=conn.execute("select hits from articles where articleId=" & articleId)(0)
%>
'打印出文章点击数
document.write(<%=hits%>)
打造静态网页的站点
随着网站访问量的加大，每次从数据库读取都是以效率作为代价的，很多用ACCESS作数据库的更会深有体会，静态页加在搜索时，也会被优先考虑。互联网上流行的做法是将数据源代码写入数据库再从数据库读取生成静态面，这样无形间就加大了数据库。将现有的ASP页直接生成静态页，将会节省很多。
下面的例子是将、index.asp?id=1/index.asp?id=2/index.asp?id=3/这三个动态页面，分别生成index1.htm,index2.htm,index3.htm存在根目录下面：
<%
dim strUrl,Item_Classid,id,FileName,FilePath,Do_Url,Html_Temp
Html_Temp="<UL>"
For i=1 To 3
Html_Temp = Html_Temp&"<LI>"
Item_Classid = i
FileName = "Index"&Item_Classid&".htm"
FilePath = Server.MapPath("/")&"\"&FileName
Html_Temp = Html_Temp&FilePath&"</LI>"
Do_Url = "http://"
Do_Url = Do_Url&Request.ServerVariables("SERVER_NAME")&"/main/index.asp"
Do_Url = Do_Url&"?Item_Classid="&Item_Classid
strUrl = Do_Url
dim objXmlHttp
set objXmlHttp = Server.CreateObject("Microsoft.XMLHTTP")
objXmlHttp.open "GET",strUrl,false
objXmlHttp.send()
Dim binFileData
binFileData = objXmlHttp.responseBody
Dim objAdoStream
set objAdoStream = Server.CreateObject("ADODB.Stream")
objAdoStream.Type = 1
objAdoStream.Open()
objAdoStream.Write(binFileData)
objAdoStream.SaveToFile FilePath,2
objAdoStream.Close()
Next
Html_Temp = Html_Temp&"<UL>"
%>
<%
Response.Write ( "成功生成文件：" )
Response.Write ( "<BR>" )
Response.Write Html_Temp
%>
|
